Работа с типом Дата в 1С Предприятие 8.3

Опубликовано автором

Пример:

&НаКлиенте
Процедура ВыполнитьКод(Команда)
 
    /// Как инициализировать дату константой в 1с 8.3, 8.2
 
    Дата = '20130724'; // 24.07.2013
 
    /// Как преобразовать строку в дату в 1с 8.3, 8.2
 
    Дата = Дата("20130724"); // 24.07.2013
 
    /// Как инициализировать дату отдельными компонентами в 1с 8.3, 8.2
 
    Дата = Дата(2013, 07, 24); // 24.07.2013
 
    /// Как указать в дате часы, минуты и секунды в 1с 8.3, 8.2
 
    Дата = '20130724132506'; // 24 июля 2013 г. 13 ч. 25 мин. 6 сек.
 
    /// Как узнать год (месяц, день, час, минута, секунда) у
    /// даты в 1с 8.3, 8.2
 
    Г =  Год(Дата); // 2013
    М =  Месяц(Дата); // 7
    Д =  День(Дата); // 24
    Ч =  Час(Дата); // 13
    Ми = Минута(Дата); // 25
    С =  Секунда(Дата); // 6
 
    /// Как получить текущую дату в 1с 8.3, 8.2
 
    Сообщить(ТекущаяДата());
 
    /// Операции с датой в 1с 8.3, 8.2
 
    Сообщить(ТекущаяДата() + 1); // прибавили секунду
 
    Сообщить(ДобавитьМесяц(ТекущаяДата(), 1)); // прибавили месяц
    Сообщить(ДобавитьМесяц(ТекущаяДата(), -1)); // отняли месяц
 
    /// Вспомогательные функции для работы с датой в 1с 8.3, 8.2
 
    Дата = '20130110125905'; // 10 января 2013 года 12:59:05
 
    Сообщить(ДеньГода(Дата)); // 10
 
    Сообщить(ДеньНедели(Дата)); // 4 т.е. четверг (нумерация с понедельника)
 
    Сообщить(НеделяГода(Дата)); // 2
 
    Сообщить(НачалоГода(Дата)); // 01.01.2013 0:00:00
    Сообщить(КонецГода(Дата)); // 31.12.2013 23:59:59
 
    Сообщить(НачалоКвартала(Дата)); // 01.01.2013 0:00:00
    Сообщить(КонецКвартала(Дата)); // 31.03.2013 23:59:59
 
    Сообщить(НачалоМесяца(Дата)); // 01.01.2013 0:00:00
    Сообщить(КонецМесяца(Дата)); // 31.01.2013 23:59:59
 
    Сообщить(НачалоНедели(Дата)); // 07.01.2013 0:00:00
    Сообщить(КонецНедели(Дата)); // 13.01.2013 23:59:59
 
    Сообщить(НачалоДня(Дата)); // 10.01.2013 0:00:00
    Сообщить(КонецДня(Дата)); // 10.01.2013 23:59:59
 
    Сообщить(НачалоЧаса(Дата)); // 10.01.2013 12:00:00
    Сообщить(КонецЧаса(Дата)); // 10.01.2013 12:59:59
 
    Сообщить(НачалоМинуты(Дата)); // 10.01.2013 12:59:00
    Сообщить(КонецМинуты(Дата)); // 10.01.2013 12:59:59 
 
КонецПроцедуры